***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec 20, 2017                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BR210-AU A K 
.param
+vc1 = 2.534e-4
+rr1 = 1.558e-3
+vc2 = 4.558e-2
+tc1 = 9.513e-2
+tc2 = 4.956e-2
gdiode K A value={(vc1*v(K,A)+rr1*exp(vc2*v(K,A)))*1e-6*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d1 A K sbd
.model sbd d
***** flag parameter ***
+level = 1                     
***** dc model parameter ***
+ibv = 0.5e-3                   
+ is = 3.414e-9
+  n = 1.057
+ rs = 6.627e-2     
+ikf = 0.05
+ bv = 110                     
***** capacitance parameter ***
+cjo = 2.019e-10  
+  m = 4.728e-1
+ vj = 5.570e-1 
+ fc = 0.5                      
***** temperature coefficient ***
+tnom = 25                     
+  eg = 8.541e-1            
+ xti = 3   
+trs1 = -3.378e-3    
+trs2 = -1.727e-5   
+tikf = -3e-3
.ends BR210-AU
*$
